Módulo 8 · Aula 8.2 · GDScript: variáveis, funções e decisões

Objetivos de aprendizagem

1. Anexar um script a um nó e entender extends.
2. Criar variáveis e constantes com tipo (int, float, String, bool).
3. Escrever funções que recebem valores e devolvem resultado.
4. Usar if/elif/else e for, e ver o resultado com print no painel Saída.
5. Saber quando roda _ready e quando roda _process.

Pré-requisitos

Aula 8.1. Módulo 1 (variáveis, condições, repetições e blocos personalizados no Scratch).

Materiais

Godot 4.7 com o projeto exemplos/laboratorio, cena cenas/ola_godot.tscn.

Conceitos

Script. Arquivo .gd ligado a um nó. A primeira linha, extends Node, diz de que tipo é o nó: o script ganha tudo o que aquele nó sabe fazer.

Indentação manda. Em GDScript, o que fica "dentro" de uma função ou de um if é marcado pelo recuo (tecla Tab), como no Python. Recuo errado é erro.

Variável e constante.

var sementes := 3          # variável: muda durante o jogo
const PRECO := 2.5         # constante: nunca muda
var nome: String = "Ana"   # tipo escrito por extenso

:= deixa o Godot descobrir o tipo pelo valor. Com tipo, o editor avisa antes de rodar quando algo não combina.

Função. Um bloco com nome, como o "Criar um Bloco" do Scratch (Aula 1.8). Pode receber valores e devolver um resultado com return.

func valor_total(quantidade: int) -> float:
    return quantidade * PRECO

Funções que o Godot chama sozinho.

delta é o tempo, em segundos, desde o quadro anterior.

Exemplos

Tutorial passo a passo

Parte A. Ler e rodar (60 min)

1. Abra o laboratório, a cena ola_godot.tscn e o script ola.gd (ícone de pergaminho ao lado do nó Ola).
2. Execute a cena atual. Veja o painel Saída: as linhas do print aparecem na ordem do código (captura abaixo).
3. Explique cada linha da Saída apontando a linha do código que a escreveu.

Parte B. Primeiro script próprio (120 min)

4. No seu projeto da Aula 8.1, selecione o nó raiz e use Adicionar Script (o botão de pergaminho com + da aba Cena; a dica diz "Associar um novo script, ou um já existente, ao nó selecionado"). Na janela Criar Script, confira Herda: e Caminho: e clique em Criar.
5. Escreva um _ready que cria var vidas := 3, tira 1 e mostra com print.
6. Escreva uma função dobro(numero: int) -> int e mostre dobro(21).

Parte C. Decisões e repetições (150 min)

7. Uma variável pontos. Se for 10 ou mais, print("Ganhou!"); senão, print("Faltam ", 10 - pontos).
8. Com for i in 5, mostre a tabuada do 7 até 7 × 5.
9. Com for i in range(1, 11), mostre de 1 a 10.

Parte D. _process (90 min)

10. Crie var tempo := 0.0 e, em _process(delta), faça tempo += delta. Mostre com print só quando tempo passar de 3 (e depois volte para 0). Isso é um relógio feito à mão.
11. Compare com o temporizador do GDevelop (Aula 3.8).

Imagens

• ../../../recursos/imagens/godot/captura-godot-ola-saida.png: script ola.gd e o painel Saída com o resultado.

Indicação da interface

O código completo

exemplos/laboratorio/scripts/ola.gd:

extends Node

const PRECO := 2.5   # constante: não muda durante o jogo

var nome := "Sertanejo"
var sementes := 3


func _ready() -> void:
	print("Olá, Godot! Eu sou o ", nome)
	print("Tenho ", sementes, " sementes.")
	sementes += 2
	print("Agora tenho ", sementes, " sementes.")
	print("Elas valem ", valor_total(sementes), " reais.")
	if sementes >= 5:
		print("Dá para plantar uma fileira!")
	else:
		print("Ainda é pouco.")
	for volta in 3:
		print("Volta número ", volta)


func valor_total(quantidade: int) -> float:
	return quantidade * PRECO

Saída (conferida no Godot 4.7.2):

Olá, Godot! Eu sou o Sertanejo
Tenho 3 sementes.
Agora tenho 5 sementes.
Elas valem 12.5 reais.
Dá para plantar uma fileira!
Volta número 0
Volta número 1
Volta número 2

Explicação do código

• print junta vários valores separados por vírgula.
• for volta in 3 conta 0, 1, 2: começa no zero, como as listas.
• -> void diz que _ready não devolve nada; -> float diz que valor_total devolve número com vírgula.
• O 12.5 sai com ponto: em código, o separador decimal é o ponto. Para mostrar "12,50" ao jogador, é preciso formatar o texto (Aula 8.8).

Resultado esperado

Script próprio com variáveis, função, if e for, e a Saída explicada linha a linha.

Problemas comuns

Exercício guiado

O que aparece na Saída?

var a := 10
a -= 3
if a > 5:
	print("grande ", a)
else:
	print("pequeno ", a)

(Resposta: grande 7.)

Desafio individual

Escreva func eh_par(n: int) -> bool e use num for de 1 a 10 para mostrar só os pares. Dica: n % 2 == 0.

Desafio avançado (opcional)

Escreva uma função que recebe a quantidade de sementes e devolve o texto certo no singular ou plural ("1 semente", "3 sementes"). O Sementes em Godot usa essa ideia na tela de fim.

Critérios de avaliação

• Código com recuo certo, sem erros no editor.
• Variáveis com nomes que dizem o que guardam, em português e sem acento.
• Explica o que cada linha faz.

Checklist de conclusão

• Rodei o ola.gd e expliquei a Saída
• Criei e anexei um script
• Fiz uma função com return
• Usei if e for
• Fiz um relógio com _process e delta

Extensão

Matemática: escreva uma função que calcula a área de um retângulo e outra o perímetro. Teste com 3 × 4.